QT_QPA_DEFAULT_PLATFORM = bsdfb

MAKEFILE_GENERATOR      = UNIX
CONFIG                 += incremental
QMAKE_INCREMENTAL_STYLE = sublib

include(../../freebsd-clang/qmake.conf)

load(device_config)

# modifications to g++-unix.conf
QMAKE_CC                = $${CROSS_COMPILE}cc
QMAKE_CXX               = $${CROSS_COMPILE}c++
QMAKE_LINK              = $${QMAKE_CXX}
QMAKE_LINK_SHLIB        = $${QMAKE_CXX}

# modifications to linux.conf
QMAKE_AR                = $${CROSS_COMPILE}ar cqs
QMAKE_OBJCOPY           = $${CROSS_COMPILE}objcopy
QMAKE_NM                = $${CROSS_COMPILE}nm -P
QMAKE_STRIP             = $${CROSS_COMPILE}strip

# Do not set QMAKE_INCDIR to system include here
# it messes up system include order. --sysroot is
# sufficient. See link for details:
# https://bugs.freebsd.org/bugzilla/show_bug.cgi?id=213217
QMAKE_LIBDIR_POST       = $$[QT_SYSROOT]/usr/lib
